Backup SD-Card Hassio on Windows?

Installation Home Assistant OS
41

Yes it’s just a zip file so any unzip will work. It’s about 3 levels deep of unzipping and is the largest zip in the snapshot.

42

When i try to unzip “homeassistant.tar.gz” (with 7z) it gives me an error:
cannot open file as archive
it’s around 1 gb and it should have a passoword (as i was giving a password when creating the full snapshot)

43

Is there a way to automatically save only configuration groups automations files? I’ve others 3 home assistant with a big work inside each one and feel unsafe with snapshots.
90% of my job is only inside configuration files

44

Other people have issues similar when they encrypt with a password. I have never used one for the snapshots.

45

Ok thanks for the suggestion. I’ll not use password anymore and hope that only this is the problem. Anyway will save manually that files on order to have a more easy “backup”

46

I am trying to do exactly what you did. Would you please help me? Can you please post your robocopy code? I can access the pi in Windows Explorer without problems however robocopy gives me an error.

Accessing Source Directory \\192.168.XX.XXX
The specified path is invalid.

Thanks in advance

47

Here you go…
You’ll need to change a few things to suit your specific setup (obviously!)

@echo off

REM --- Robocopy
REM     --------
REM
REM --- Copy Home Assistant Snapshots and config folder to OneDrive 
REM
REM --- Parameters used:
REM
REM --- /MIR : MIRror a directory tree 
REM
REM --- /DST : Compensate for one-hour DST time differences 
REM
REM --- /XD : eXclude Directories 
REM
REM --- /XF : eXclude Files 

echo ====================================================================
echo COPYING - Home Assistant Snapshots
echo ====================================================================

echo.
echo === 
echo === Mapping to HASSIO...
echo ===
echo.
 
net use x: \\192.168.1.25\backup
x:

echo === Done


echo.
echo === 
echo === Deleting old snapshots (matching *.tar) on
echo === HASSIO that are older than 8 days...
echo ===
echo.
 
forfiles /m *.tar /d -8 /c "cmd /c del @file"

echo === Done


echo.
echo === 
echo === Robocopy new snapshots on HASSIO to
echo === OneDrive folder on PC...
echo ===
echo.

robocopy "\\192.168.1.25\backup" "D:\Users\Me\OneDrive\Home Assistant Backups"

echo === Done


echo.
echo === 
echo === Deleting old snapshots from OneDrive folder
echo === on PC that are older than 28 days...
echo === 
echo.

forfiles /m *.tar /p "D:\Users\Me\OneDrive\Home Assistant Backups" /d -28 /c "cmd /c del @file"

echo === Done


echo.
echo === 
echo === Robocopy current HASSIO config folder
echo === to OneDrive folder on PC...
echo ===
echo.

robocopy "\\192.168.1.25\config" "D:\Users\Me\OneDrive\Home Assistant Backups\Latest Config"  /MIR /DST /XF *.db *.log core.68 /XD *__pycache__ deps tts .*

echo === Done


echo.
echo === 
echo === List of current snapshots on HASSIO...
echo ===
echo.

dir x: /o:-d /a:-d

pause

echo === Done


echo.
echo === 
echo === List of current snapshots in OneDrive folder on PC...
echo ===
echo.

dir "D:\Users\Me\OneDrive\Home Assistant Backups" /o:-d /a:-d

pause


REM --- Remove drive mapping
REM ---
net use x: /delete /y